home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 #2 / Ham Radio 2000 - Volume 2.iso / HAMV2 / MISC / HCAL-27 / CYLLOAD.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1997-02-16  |  9.2 KB  |  311 lines
  1. 10  'CYLLOAD - Cylinder-Loaded Dipole - 17 JAN 97 rev. 16 FEB 97
  2. 20  REM 'ref. ARRL ANTENNA BOOK, 17th ed. page 2-40
  3. 30  IF EX$=""THEN EX$="EXIT"
  4. 40  CLS:KEY OFF
  5. 50  COLOR 7,0,1
  6. 60  PI=3.14159
  7. 70  U$="####.###":V$="=###.###":W$="####.##"
  8. 80  UL$=STRING$(80,205)
  9. 90  '
  10. 100  '.....start
  11. 110  CLS:COLOR 15,2:D=0:C=0
  12. 120  PRINT " CYLOAD Short Cylinder-Loaded Dipole";
  13. 130  PRINT TAB(57)"by George Murphy VE3ERP ";
  14. 140  COLOR 1,0:PRINT STRING$(80,223);
  15. 150  COLOR 7,0
  16. 160  LOCATE 2:GOSUB 1970  'diagram
  17. 170  COLOR 15,1:LOCATE ,25:PRINT " Designed by Hal Wright, W9UYA ":COLOR 7,0
  18. 180  PRINT "   The CYLOAD is a dipole with wire elements end-loaded by metal ";
  19. 190  PRINT "cylinders,"
  20. 200  PRINT "   allowing length L to be considerably less than a normal ";
  21. 210  PRINT "unloaded dipole."
  22. 220  PRINT UL$;
  23. 230  '.....standard disclaimer
  24. 240  OPEN"I",1,"\data\docfiles\antenna.doc"
  25. 250  IF EOF(1)THEN 270
  26. 260  INPUT#1,NOTE$:PRINT "   ";NOTE$:GOTO 250
  27. 270  CLOSE
  28. 280  PRINT UL$;
  29. 290  PRINT " Press number in < > for:
  30. 300  PRINT UL$;
  31. 310  PRINT "   < 1 >  CYLOAD antenna design"
  32. 320  PRINT "   < 0 >  EXIT";
  33. 330   Z$=INKEY$:IF Z$=""THEN 330
  34. 340   IF Z$="0"THEN CLS:RUN EX$
  35. 350   IF Z$="1"THEN 380
  36. 360  GOTO 330
  37. 370  '
  38. 380  '.....preface
  39. 390  LN=2:GOSUB 1930   'clear screen
  40. 400  LOCATE 2:COLOR 1,0:PRINT STRING$(80,223);:COLOR 7,0
  41. 410  GOSUB 2110  'notes#1
  42. 420  GOSUB 2980
  43. 430  LN=3:GOSUB 1930
  44. 440  GOSUB 2590  'notes#2
  45. 450  GOSUB 2980
  46. 460  COLOR 0,7:LOCATE 25,5
  47. 470  PRINT " Do you want to enter data in (m)etric or (i)mperial/USA units?";
  48. 480  PRINT "   (m/i) ";
  49. 490  COLOR 7,0
  50. 500  Z$=INKEY$:IF Z$=""THEN 500
  51. 510  IF Z$="m"THEN UM$="cm.":UM=2.54:GOTO 540
  52. 520  IF Z$="i"THEN UM$="in.":UM=1:GOTO 540
  53. 530  GOTO 500
  54. 540  LN=3:GOSUB 1930:LOCATE 2
  55. 550  GOSUB 1970    'diagram
  56. 560  '
  57. 570  '.....input data
  58. 580  INPUT " ENTER: Frequency...............................(MHz)";F
  59. 590  ZZ=F:GOSUB 1880:PRINT " MHz"
  60. 600  '
  61. 610  IPD=32.8/F
  62. 620  PRINT SPC(8);"Unit of electrical length................ 1<UNK! {00F8}>=";
  63. 630  PRINT USING U$;IPD*UM;:PRINT " ";UM$
  64. 640  '
  65. 650  QW=2808/F:QD=QW*F/32.8
  66. 660  PRINT SPC(8);"Approx. length of a DEFSTR-wave unloaded monopole=";
  67. 670  PRINT USING U$;QW*UM;:PRINT " ";UM$;" ";USING V$;QD;:PRINT "<UNK! {00F8}>"
  68. 680  LN=CSRLIN:LOCATE LN+2,9:COLOR 0,7
  69. 690  PRINT " Overall length of 65<UNK! {00F8}> (";USING U$;65*IPD*UM;
  70. 700  PRINT " ";UM$;") or more is recommended.     "
  71. 710  LOCATE ,9
  72. 720  PRINT " At lengths below 65<UNK! {00F8}> the design equations begin to lose accuracy."
  73. 730  LOCATE ,9
  74. 740  PRINT " Lengths below 55<UNK! {00F8}> (";USING U$;55*IPD*UM;
  75. 750  PRINT " ";UM$;") are not recommended.            "
  76. 760  COLOR 7,0:LOCATE LN
  77. 770  PRINT " ENTER: Overall length of your CYLOAD monopole..(";UM$;") L=";
  78. 780  INPUT Z
  79. 790  LG=Z/UM:LGD=LG*F/32.8
  80. 800  ZZ=LG*UM:GOSUB 1880:PRINT " ";UM$;" ";USING V$;LGD;:PRINT "<UNK! {00F8}>"
  81. 810  LOCATE CSRLIN-1,52:PRINT "L="
  82. 820  LN=CSRLIN:GOSUB 1930
  83. 830  '
  84. 840  IF C THEN 960
  85. 850  GOSUB 1690
  86. 860  LOCATE 24,9:COLOR 0,7
  87. 870  PRINT " Cylinder length less than 5<UNK! {00F8}> (";USING U$;5*IPD*UM;
  88. 880  PRINT " ";UM$;") not recommended ";
  89. 890  COLOR 15,0:LOCATE 22
  90. 900  PRINT " ENTER: Length of cylindrical load..............(";UM$;") C=";
  91. 910  INPUT Z
  92. 920  COLOR 7,0
  93. 930  CC=Z/UM:C=CC*F/32.8:W=LGD-C:HI=32.8*W/F
  94. 940  GOSUB 1930
  95. 950  '
  96. 960  PRINT " INNER WIRE SECTION:"
  97. 970  J=HI*F/32.8
  98. 980  PRINT SPC(8);"Length of wire section.....................W=";
  99. 990  PRINT USING U$;HI*UM;:PRINT " ";UM$;:PRINT " ";USING V$;J;:PRINT "<UNK! {00F8}>"
  100. 1000  '
  101. 1010  COLOR 0,7
  102. 1020  PRINT " Do you want wire size in millimeters, inches, or AWG# ?   (m/i/a) "
  103. 1030  Z$=INKEY$:IF Z$=""THEN 1030
  104. 1040  IF Z$="m"THEN M$="mm.":GOTO 1090
  105. 1050  IF Z$="i"THEN M$="in.":GOTO 1090
  106. 1060  IF Z$="a"THEN M$="AWG":GOTO 1090
  107. 1070  GOTO 1030
  108. 1080  '
  109. 1090  COLOR 7,0:LN=CSRLIN-1:GOSUB 1930
  110. 1100  PRINT " ENTER: Wire diameter...........................(";M$;")";:INPUT Z
  111. 1110  IF Z$="m"THEN D=Z/25.4:GOTO 1160
  112. 1120  IF Z$="i"THEN D=Z:GOTO 1160
  113. 1130  '.....AWG sizes
  114. 1140  KK=(0.46/0.005)^(1/39)
  115. 1150  D=0.46/KK^(Z+3)      'wire diameter in inches
  116. 1160  ZZ=D*UM:GOSUB 1880:PRINT " ";UM$
  117. 1170  '
  118. 1180  LD=HI/D
  119. 1190  PRINT SPC(8);"Wire length/diameter ratio...................";
  120. 1200  PRINT USING U$;LD;:PRINT ":1"
  121. 1210  '
  122. 1220  ZW=60*(LOG(4*HI/D)-1)
  123. 1230  PRINT SPC(8);"Impedance of wire section.................Zw=";
  124. 1240  PRINT USING U$;ZW;:PRINT " ohms"
  125. 1250  '
  126. 1260  PRINT " END LOADING CYLINDER:"
  127. 1270  HC=32.8*C/F
  128. 1280  PRINT SPC(8);"Cylinder length............................C=";
  129. 1290  PRINT USING U$;HC*UM;:PRINT " ";UM$;" ";USING V$;C;:PRINT "<UNK! {00F8}>"
  130. 1300  '
  131. 1310  ZC=ZW*TAN(C*PI/180)*TAN(W*PI/180)
  132. 1320  PRINT SPC(8);"Impedance of loading cylinder.............Zc=";
  133. 1330  PRINT USING U$;ZC;:PRINT " ohms"
  134. 1340  '
  135. 1350  HD=EXP(ZC/60+1)/4
  136. 1360  PRINT SPC(8);"Cylinder Length/diameter ratio...............";
  137. 1370  PRINT USING U$;HD;:PRINT ":1
  138. 1380  '
  139. 1390  DIA=HC/HD
  140. 1400  PRINT SPC(8);"Cylinder diameter..........................D=";
  141. 1410  PRINT USING U$;DIA*UM;:PRINT " ";UM$
  142. 1420  LOCATE 23
  143. 1430  COLOR 0,7:PRINT " Do you want to adjust cylinder diameter?   (y/n) ";
  144. 1440  COLOR 23,0:PRINT "CSRLIN"
  145. 1450  COLOR 7,0:LOCATE 24
  146. 1460  PRINT " Adjust only slightly to use a similar size tube, otherwise use ";
  147. 1470  PRINT "another length.";
  148. 1480  Z$=INKEY$:IF Z$=""THEN 1480
  149. 1490  IF Z$="n"THEN LN=23:GOSUB 1930:GOTO 1650
  150. 1500  IF Z$="y"THEN 1520
  151. 1510  GOTO 1480
  152. 1520  LOCATE 22
  153. 1530  PRINT " ENTER: New cylinder diameter...................(";UM$;") D=";
  154. 1540  INPUT Z:Z=Z/UM
  155. 1550  HD=HC/Z
  156. 1560  ZC=60*(LOG(4*HD)-1)
  157. 1570  ZW=ZC/TAN(C*PI/180)/TAN(W*PI/180)
  158. 1580  LD=EXP(ZW/60+1)/4
  159. 1590  HI=LD*D:LG=HI+HC
  160. 1600  LGD=LG*F/32.8
  161. 1610  LN=13:GOSUB 1930
  162. 1620  FOR JJ=12 TO 23:LOCATE JJ,74:PRINT STRING$(6,32);:NEXT JJ:LOCATE 12
  163. 1630  GOTO 800
  164. 1640  '
  165. 1650  '.....end
  166. 1660  GOSUB 2980:GOTO 100
  167. 1670  END
  168. 1680  '
  169. 1690  '.....sample cylinders
  170. 1700  PRINT " Typical cylinders for this antenna with .064";CHR$(34);" wire:"
  171. 1710  FOR C=5 TO 21 STEP 2
  172. 1720  W=LGD-C:HI=32.8*W/F
  173. 1730  J=HI*F/32.8
  174. 1740  D=0.064
  175. 1750  LD=HI/D
  176. 1760  ZW=60*(LOG(4*HI/D)-1)
  177. 1770  HC=32.8*C/F
  178. 1780  ZC=ZW*TAN(C*PI/180)*TAN(W*PI/180)
  179. 1790  HD=EXP(ZC/60+1)/4
  180. 1800  DIA=HC/HD
  181. 1810  PRINT " Length:";USING W$;C;
  182. 1820  PRINT "<UNK! {00F8}> (";USING W$;HC*UM;
  183. 1830  PRINT " ";UM$;" ) x ";USING W$;DIA*UM;
  184. 1840  PRINT " ";UM$;" diameter"
  185. 1850  NEXT C
  186. 1860  RETURN
  187. 1870  '
  188. 1880  '.....format input line
  189. 1890  LOCATE CSRLIN-1:PRINT SPC(7);
  190. 1900  LOCATE CSRLIN,47:PRINT STRING$(7,".");USING U$;ZZ;
  191. 1910  RETURN
  192. 1920  '
  193. 1930  '.....clear screen to bottom
  194. 1940  VIEW PRINT LN TO 24:CLS:VIEW PRINT:LOCATE LN
  195. 1950  RETURN
  196. 1960  '
  197. 1970  '.....diagram
  198. 1980  T=13
  199. 1990  COLOR 1,7
  200. 2000  LOCATE ,T:PRINT STRING$(55,223)
  201. 2010  COLOR 0,7
  202. 2020  LOCATE ,T:PRINT "     CALLDEFSNGSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUND L SOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDDEFDBLCALLDEFSNGSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUND L SOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDDEFDBLCALL     "
  203. 2030  LOCATE ,T:PRINT " - -/BSAVESOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDBSAVESOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDCOLORVARPTRSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDBSAVESOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDBSAVE/- - "
  204. 2040  LOCATE ,T:PRINT "     CLSSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUND'    wire   PRESET'  wire    CLSSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUND'     "
  205. 2050  LOCATE ,T:PRINT "     CALLDEFSNGSOUNDSOUND C SOUNDSOUNDDEFDBLCALLDEFSNGSOUNDSOUNDSOUND W SOUNDSOUNDSOUNDDEFDBLOPENDEFSNGSOUNDSOUNDSOUND W SOUNDSOUNDSOUNDDEFDBLCALLDEFSNGSOUNDSOUND C SOUNDSOUNDDEFDBLCALL     "
  206. 2060  LOCATE ,T:PRINT "     D^ cylinder           OPEN           D^ cylinder     "
  207. 2070  LOCATE ,T:PRINT "                50-75 - coaxial feedline               "
  208. 2080  COLOR 7,0
  209. 2090  RETURN
  210. 2100  '
  211. 2110  '.....notes #1
  212. 2120  M=7
  213. 2130  PRINT TAB(M);
  214. 2140  PRINT "  CYLOAD is an EXPERIMENTAL antenna devised by Hal Wright, W9UYA,"
  215. 2150  PRINT TAB(M);
  216. 2160  PRINT "who reports that it performs well. It does not claim any practical"
  217. 2170  PRINT TAB(M);
  218. 2180  PRINT "advantage over other short dipole types but it does re-open an area"
  219. 2190  PRINT TAB(M);
  220. 2200  PRINT "of antenna design not often mentioned in current amateur radio"
  221. 2210  PRINT TAB(M);
  222. 2220  PRINT "literature. The program provides calculations for those who might"
  223. 2230  PRINT TAB(M);
  224. 2240  PRINT "like to experiment further with this concept."
  225. 2250  PRINT TAB(M);
  226. 2260  PRINT "  Previous discussions of cylindrical loads in amateur radio"
  227. 2270  PRINT TAB(M);
  228. 2280  PRINT "literature have assumed the length and diameter of the loading"
  229. 2290  PRINT TAB(M);
  230. 2300  PRINT "cylinder to be equal. CYLOAD does not impose this limitation."
  231. 2310  PRINT TAB(M);
  232. 2320  PRINT "  Cylinders may be rolled from roofers' flashing sheets or metal"
  233. 2330  PRINT TAB(M);
  234. 2340  PRINT "screening, or cut from copper water pipe or aluminum tubing."
  235. 2350  PRINT TAB(M);
  236. 2360  PRINT "  Practical field tests by W9UYA indicate that antennas built to"
  237. 2370  PRINT TAB(M);
  238. 2380  PRINT "this design resonate at very close to the design frequency in the"
  239. 2390  PRINT TAB(M);
  240. 2400  PRINT "range of 7 MHz to 21.5 MHz. At 24.8 - 148 MHz it may be advisable"
  241. 2410  PRINT TAB(M);
  242. 2420  PRINT "to increase the design length of the inner wires by about 10% to"
  243. 2430  PRINT TAB(M);
  244. 2440  PRINT "allow for pruning to resonance at the design frequency."
  245. 2450  PRINT TAB(M);
  246. 2460  PRINT "  The fundamental equation for a CYLOAD antenna is:"
  247. 2470  PRINT TAB(M);
  248. 2480  PRINT "Zc = Zw x tan Lw x tan Lc, where: Zc = impedance of cylinder (-)"
  249. 2490  PRINT TAB(M);
  250. 2500  PRINT "                                  Zw = impedance of wire (-)"
  251. 2510  PRINT TAB(M);
  252. 2520  PRINT "                                  Lw = length of wire (<UNK! {00F8}>)"
  253. 2530  PRINT TAB(M);
  254. 2540  PRINT "                                  Lc = length of cylinder (<UNK! {00F8}>)"
  255. 2550  PRINT TAB(M);
  256. 2560  PRINT "  A transmatch at the station end of the feedline is recommended.";
  257. 2570  RETURN
  258. 2580  '
  259. 2590  '.....notes#2
  260. 2600  PRINT TAB(M);
  261. 2610  PRINT "  Special thanks go to L.B.Cebik, W4RNL, for his encouragement in"
  262. 2620  PRINT TAB(M);
  263. 2630  PRINT "the development of the CYLOAD antenna, and for the many computer"
  264. 2640  PRINT TAB(M);
  265. 2650  PRINT "models he has run to check out the viability and accuracy of the"
  266. 2660  PRINT TAB(M);
  267. 2670  PRINT "design. These models and the practical field tests by Hal Wright,"
  268. 2680  PRINT TAB(M);
  269. 2690  PRINT "W9UYA, indicate that good performance characteristics are possible"
  270. 2700  PRINT TAB(M);
  271. 2710  PRINT "in the 3.5 to 28 MHz range."
  272. 2720  PRINT TAB(M);
  273. 2730  PRINT "  The CYLOAD concept is based on equations usually applied to cases"
  274. 2740  PRINT TAB(M);
  275. 2750  PRINT "where the conductor diameter is an insignificant percentage of a"
  276. 2760  PRINT TAB(M);
  277. 2770  PRINT "wavelength (e.g., at LF and VLF frequencies). At HF and above the"
  278. 2780  PRINT TAB(M);
  279. 2790  PRINT "percentage becomes more significant and the equations become"
  280. 2800  PRINT TAB(M);
  281. 2810  PRINT "increasingly more inaccurate. Above 21 MHz allowance should be made"
  282. 2820  PRINT TAB(M);
  283. 2830  PRINT "for further experimentation and pruning."
  284. 2840  PRINT TAB(M);
  285. 2850  PRINT "  The program provides for slightly altering the design diameter"
  286. 2860  PRINT TAB(M);
  287. 2870  PRINT "of the cylinder to suit a similar size standard pipe or tube. This"
  288. 2880  PRINT TAB(M);
  289. 2890  PRINT "feature must be used with caution, since changing the diameter"
  290. 2900  PRINT TAB(M);
  291. 2910  PRINT "decreases the accuracy of all other calculations. A better way to"
  292. 2920  PRINT TAB(M);
  293. 2930  PRINT "arrive at a different diameter is to re-run the program and select"
  294. 2940  PRINT TAB(M);
  295. 2950  PRINT "a different cylinder length."
  296. 2960  RETURN
  297. 2970  '
  298. 2980  'HARDCOPY
  299. 2990  GOSUB 3100:LOCATE 25,2:COLOR 14,6
  300. 3000  PRINT " Press 1 to print screen, 2 to print screen & ";
  301. 3010  PRINT "advance paper, or 3 to continue.";:COLOR 7,0
  302. 3020  Z$=INKEY$:IF Z$="3"THEN GOSUB 3100:RETURN
  303. 3030  IF Z$="1"OR Z$="2"THEN GOSUB 3100:GOTO 3050
  304. 3040  GOTO 3020
  305. 3050  FOR QX=1 TO 24:FOR QY=1 TO 80
  306. 3060  LPRINT CHR$(SCREEN(QX,QY));
  307. 3070  NEXT QY:NEXT QX
  308. 3080  IF Z$="2"THEN LPRINT CHR$(12)
  309. 3090  GOTO 2990
  310. 3100  LOCATE 25,1:PRINT STRING$(80,32);:RETURN
  311.